MCS-51單片機實用子程序庫(96年版)
作者:佚名　　轉貼自:摘自網絡　　點擊數:10203　　文章錄入:admin

目前已有若干版本的子程序庫公開發表,它們各有特色。筆者在1988年也編制了兩個
子程序庫(定點子程序庫和浮點子程序庫),并在相容性、透明性、容錯性和算法優化方面作了一些工作。本程序庫中的開平方算法為筆者研究的快速逼近算法,它能達到牛頓迭代法同樣的精度,而速度加快二十倍左右,超過雙字節定點除法的速度。經過八年來全國廣大用戶的實際使用,反饋了不少信息,陸續擴充了一些新的子程序,糾正了一些隱含錯誤,成為現在這個最新版本。
本子程序庫對《單片機應用程序設計技術》一書附錄中的子程序庫作了重大修訂:
(1)按當前流行的以 IBM PC 為主機的開發系統對匯編語言的規定,將原子程序庫
的標號和位地址進行了調整,讀者不必再進行修改,便可直接使用。
(2)對浮點運算子程序庫進行了進一步的測試和優化,對十進制浮點數和二進制浮
點數的相互轉換子程序進行了徹底改寫,提高了運算精度和可靠性。
(3)新增添了若干個浮點子程序(傳送、比較、清零、判零等),使編寫數據處理
程序的工作變得更簡單直觀。
在使用說明中開列了最主要的幾項:標號、入口條件、出口信息、影響資源、堆棧需求,各項目的意義請參閱《單片機應用程序設計技術》第六章 6.3.7 節的內容。程序清單中開列了四個欄目:標號、指令、操作數、注釋。為方便讀者理解,注釋盡力詳細。
子程序庫的使用方法如下:
1．將子程序庫全部內容鏈接在應用程序之后,統一編譯即可。優點是簡單方便,缺點是程序太長,大量無關子程序也包含在其中。
2．僅將子程序庫中的有關部分內容鏈接在應用程序之后,統一編譯即可。有些子程序需要調用一些低級子程序,這些低級子程序也應該包含在內。優點是程序緊湊,缺點是
需要對子程序庫進行仔細刪節。

(一)MCS-51定點運算子程序庫及其使用說明
定點運算子程序庫文件名為DQ51.ASM,為便于使用,先將有關約定說明如下:
1．多字節定點操作數:用[R0]或[R1]來表示存放在由R0或R1指示的連續單元中的數據。地址小的單元存放數據的高字節。例如:[R0]=123456H,若(R0)=30H,則(30H)=12H,
(31H)=34H,(32H)=56H。
2．運算精度:單次定點運算精度為結果最低位的當量值。
3．工作區:數據工作區固定在PSW、A、B、R2~R7,用戶只要不在工作區中存放無
關的或非消耗性的信息,程序就具有較好的透明性。

(1) 標號: BCDA功能:多字節BCD碼加法

入口條件:字節數在R7中,被加數在[R0]中,加數在[R1]中。
出口信息:和在[R0]中,最高位進位在CY中。
影響資源:PSW、A、R2 堆棧需求: 2字節

BCDA: MOV A,R7 ;取字節數至R2中
MOV R2,A
ADD A,R0 ;初始化數據指針
MOV R0,A
MOV A,R2
ADD A,R1
MOV R1,A
CLR C
BCD1: DEC R0 ;調整數據指針
DEC R1
MOV A,@R0
ADDC A,@R1 ;按字節相加
DA A ;十進制調整
MOV @R0,A ;和存回[R0]中
DJNZ R2,BCD1 ;處理完所有字節
RET

(2) 標號: BCDB功能:多字節BCD碼減法

入口條件:字節數在R7中,被減數在[R0]中,減數在[R1]中。
出口信息:差在[R0]中,最高位借位在CY中。
影響資源:PSW、A、R2、R3 堆棧需求: 6字節

BCDB: LCALL NEG1 ;減數[R1]十進制取補
LCALL BCDA ;按多字節BCD碼加法處理
CPL C ;將補碼加法的進位標志轉換成借位標志
MOV F0,C ;保護借位標志
LCALL NEG1 ;恢復減數[R1]的原始值
MOV C,F0 ;恢復借位標志
RET
NEG1: MOV A,R0 ;[R1]十進制取補子程序入口
XCH A,R1 ;交換指針
XCH A,R0
LCALL NEG ;通過[R0]實現[R1]取補
MOV A,R0
XCH A,R1 ;換回指針
XCH A,R0
RET


(3) 標號: NEG功能:多字節BCD碼取補

入口條件:字節數在R7中,操作數在[R0]中。
出口信息:結果仍在[R0]中。
影響資源:PSW、A、R2、R3 堆棧需求: 2字節

NEG: MOV A,R7 ;取(字節數減一)至R2中
DEC A
MOV R2,A
MOV A,R0 ;保護指針
MOV R3,A
NEG0: CLR C
MOV A,#99H
SUBB A,@R0 ;按字節十進制取補
MOV @R0,A ;存回[R0]中
INC R0 ;調整數據指針
DJNZ R2,NEG0 ;處理完(R2)字節
MOV A,#9AH ;最低字節單獨取補
SUBB A,@R0
MOV @R0,A
MOV A,R3 ;恢復指針
MOV R0,A
RET

(4) 標號: BRLN功能:多字節BCD碼左移十進制一位(乘十)

入口條件:字節數在R7中,操作數在[R0]中。
出口信息:結果仍在[R0]中,移出的十進制最高位在R3中。
影響資源:PSW、A、R2、R3 堆棧需求: 2字節

BRLN: MOV A,R7 ;取字節數至R2中
MOV R2,A
ADD A,R0 ;初始化數據指針
MOV R0,A
MOV R3,#0 ;工作單元初始化
BRL1: DEC R0 ;調整數據指針
MOV A,@R0 ;取一字節
SWAP A ;交換十進制高低位
MOV @R0,A ;存回
MOV A,R3 ;取低字節移出的十進制高位
XCHD A,@R0 ;換出本字節的十進制高位
MOV R3,A ;保存本字節的十進制高位
DJNZ R2,BRL1 ;處理完所有字節
RET

(5) 標號: MULD功能:雙字節二進制無符號數乘法

入口條件:被乘數在R2、R3中,乘數在R6、R7中。
出口信息:乘積在R2、R3、R4、R5中。
影響資源:PSW、A、B、R2~R7 堆棧需求: 2字節

MULD: MOV A,R3 ;計算R3乘R7
MOV B,R7
MUL AB
MOV R4,B ;暫存部分積
MOV R5,A
MOV A,R3 ;計算R3乘R6
MOV B,R6
MUL AB
ADD A,R4 ;累加部分積
MOV R4,A
CLR A
ADDC A,B
MOV R3,A
MOV A,R2 ;計算R2乘R7
MOV B,R7
MUL AB
ADD A,R4 ;累加部分積
MOV R4,A
MOV A,R3
ADDC A,B
MOV R3,A
CLR A
RLC A
XCH A,R2 ;計算R2乘R6
MOV B,R6
MUL AB
ADD A,R3 ;累加部分積
MOV R3,A
MOV A,R2
ADDC A,B
MOV R2,A
RET
(6) 標號: MUL2功能:雙字節二進制無符號數平方

入口條件:待平方數在R2、R3中。
出口信息:結果在R2、R3、R4、R5中。
影響資源:PSW、A、B、R2~R5 堆棧需求: 2字節

MUL2: MOV A,R3 ;計算R3平方
MOV B,A
MUL AB
MOV R4,B ;暫存部分積
MOV R5,A
MOV A,R2 ;計算R2平方
MOV B,A
MUL AB
XCH A,R3 ;暫存部分積,并換出R2和R3
XCH A,B
XCH A,R2
MUL AB ;計算2×R2×R3
CLR C
RLC A
XCH A,B
RLC A
JNC MU20
INC R2 ;累加溢出量
MU20: XCH A,B ;累加部分積
ADD A,R4
MOV R4,A
MOV A,R3
ADDC A,B
MOV R3,A
CLR A
ADDC A,R2
MOV R2,A
RET

(7) 標號: DIVD功能:雙字節二進制無符號數除法

入口條件:被除數在R2、R3、R4、R5中,除數在R6、R7中。
出口信息:OV=0 時,雙字節商在R2、R3中,OV=1 時溢出。
影響資源:PSW、A、B、R1~R7 堆棧需求: 2字節

DIVD: CLR C ;比較被除數和除數
MOV A,R3
SUBB A,R7
MOV A,R2
SUBB A,R6
JC DVD1
SETB OV ;溢出
RET
DVD1: MOV B,#10H ;計算雙字節商
DVD2: CLR C ;部分商和余數同時左移一位
MOV A,R5
RLC A
MOV R5,A
MOV A,R4
RLC A
MOV R4,A
MOV A,R3
RLC A
MOV R3,A
XCH A,R2
RLC A
XCH A,R2
MOV F0,C ;保存溢出位
CLR C
SUBB A,R7 ;計算(R2R3-R6R7)
MOV R1,A
MOV A,R2
SUBB A,R6
ANL C,/F0 ;結果判斷
JC DVD3
MOV R2,A ;夠減,存放新的余數
MOV A,R1
MOV R3,A
INC R5 ;商的低位置一
DVD3: DJNZ B,DVD2 ;計算完十六位商(R4R5)
MOV A,R4 ;將商移到R2R3中
MOV R2,A
MOV A,R5
MOV R3,A
CLR OV ;設立成功標志
RET

(8) 標號: D457功能:雙字節二進制無符號數除以單字節二進制數

入口條件:被除數在R4、R5中,除數在R7中。
出口信息:OV=0 時,單字節商在R3中,OV=1 時溢出。
影響資源:PSW、A、R3~R7 堆棧需求: 2字節

D457: CLR C
MOV A,R4
SUBB A,R7
JC DV50
SETB OV ;商溢出
RET
DV50: MOV R6,#8 ;求平均值(R4R5/R7-→R3)
DV51: MOV A,R5
RLC A
MOV R5,A
MOV A,R4
RLC A
MOV R4,A
MOV F0,C
CLR C
SUBB A,R7
ANL C,/F0
JC DV52
MOV R4,A
DV52: CPL C
MOV A,R3
RLC A
MOV R3,A
DJNZ R6,DV51
MOV A,R4 ;四舍五入
ADD A,R4
JC DV53
SUBB A,R7
JC DV54
DV53: INC R3
DV54: CLR OV
RET
(9) 標號: DV31功能:三字節二進制無符號數除以單字節二進制數

入口條件:被除數在R3、R4、R5中,除數在R7中。
出口信息:OV=0 時,雙字節商在R4、R5中,OV=1 時溢出。
影響資源:PSW、A、B、R2~R7 堆棧需求: 2字節

DV31: CLR C
MOV A,R3
SUBB A,R7
JC DV30
SETB OV ;商溢出
RET
DV30: MOV R2,#10H ;求R3R4R5/R7-→R4R5
DM23: CLR C
MOV A,R5
RLC A
MOV R5,A
MOV A,R4
RLC A
MOV R4,A
MOV A,R3
RLC A
MOV R3,A
MOV F0,C
CLR C
SUBB A,R7
ANL C,/F0
JC DM24
MOV R3,A
INC R5
DM24: DJNZ R2,DM23
MOV A,R3 ;四舍五入
ADD A,R3
JC DM25
SUBB A,R7
JC DM26
DM25: INC R5
MOV A,R5
JNZ DM26
INC R4
DM26: CLR OV
RET ;商在R4R5中


(10) 標號: MULS功能:雙字節二進制有符號數乘法(補碼)

入口條件:被乘數在R2、R3中,乘數在R6、R7中。
出口信息:乘積在R2、R3、R4、R5中。
影響資源:PSW、A、B、R2~R7 堆棧需求: 4字節

MULS: MOV R4,#0 ;清零R4R5
MOV R5,#0
LCALL MDS ;計算結果的符號和兩個操作數的絕對值
LCALL MULD ;計算兩個絕對值的乘積
SJMP MDSE ;用補碼表示結果

(11) 標號: DIVS功能:雙字節二進制有符號數除法(補碼)

入口條件:被除數在R2、R3、R4、R5中,除數在R6、R7中。
出口信息:OV=0時商在R2、R3中,OV=1時溢出。
影響資源:PSW、A、B、R1~R7 堆棧需求: 5字節

DIVS: LCALL MDS ;計算結果的符號和兩個操作數的絕對值
PUSH PSW ;保存結果的符號
LCALL DIVD ;計算兩個絕對值的商
JNB OV,DVS1 ;溢出否？
POP ACC ;溢出,放去結果的符號,保留溢出標志
RET
DVS1: POP PSW ;未溢出,取出結果的符號
MOV R4,#0
MOV R5,#0
MDSE: JB F0,MDS2 ;用補碼表示結果
CLR OV ;結果為正,原碼即補碼,計算成功
RET
MDS: CLR F0 ;結果符號初始化
MOV A,R6 ;判斷第二操作數的符號
JNB ACC.7,MDS1;為正,不必處理
CPL F0 ;為負,結果符號取反
XCH A,R7 ;第二操作數取補,得到其絕對值
CPL A
ADD A,#1
XCH A,R7
CPL A
ADDC A,#0
MOV R6,A
MDS1: MOV A,R2 ;判斷第一操作數或運算結果的符號
JNB ACC.7,MDS3;為正,不必處理
CPL F0 ;為負,結果符號取反
MDS2: MOV A,R5 ;求第一操作數的絕對值或運算結果的補碼
CPL A
ADD A,#1
MOV R5,A
MOV A,R4
CPL A
ADDC A,#0
MOV R4,A
MOV A,R3
CPL A
ADDC A,#0
MOV R3,A
MOV A,R2
CPL A
ADDC A,#0
MOV R2,A
MDS3: CLR OV ;運算成功
RET

(12) 標號: SH2功能:雙字節二進制無符號數開平方(快速)

入口條件:被開方數在R2、R3中。
出口信息:平方根仍在R2、R3中,整數部分的位數為原數的一半,其余為小數。
影響資源:PSW、A、B、R2~R7 堆棧需求: 2字節

SH2: MOV A,R2
ORL A,R3
JNZ SH20
RET ;被開方數為零,不必運算
SH20: MOV R7,#0 ;左規次數初始化
MOV A,R2
SH22: ANL A,#0C0H ;被開方數高字節小于40H否？
JNZ SQRH ;不小于40H,左規格化完成,轉開方過程
CLR C ;每左規一次,被開方數左移兩位
MOV A,R3
RLC A
MOV F0,C
CLR C
RLC A
MOV R3,A
MOV A,R2
MOV ACC.7,C
MOV C,F0
RLC A
RLC A
MOV R2,A
INC R7 ;左規次數加一
SJMP SH22 ;繼續左規

(13) 標號: SH4功能:四字節二進制無符號數開平方(快速)

入口條件:被開方數在R2、R3、R4、R5中。
出口信息:平方根在R2、R3中,整數部分的位數為原數的一半,其余為小數。
影響資源:PSW、A、B、R2~R7 堆棧需求: 2字節

SH4: MOV A,R2
ORL A,R3
ORL A,R4
ORL A,R5
JNZ SH40
RET ;被開方數為零,不必運算
SH40: MOV R7,#0 ;左規次數初始化
MOV A,R2
SH41: ANL A,#0C0H ;被開方數高字節小于40H否？
JNZ SQRH ;不小于40H,左規格化完成
MOV R6,#2 ;每左規一次,被開方數左移兩位
SH42: CLR C ;被開方數左移一位
MOV A,R5
RLC A
MOV R5,A
MOV A,R4
RLC A
MOV R4,A
MOV A,R3
RLC A
MOV R3,A
MOV A,R2
RLC A
MOV R2,A
DJNZ R6,SH42 ;被開方數左移完兩位
INC R7 ;左規次數加一
SJMP SH41 ;繼續左規
SQRH: MOV A,R2 ;規格化后高字節按折線法分為三個區間
ADD A,#57H
JC SQR2
ADD A,#45H
JC SQR1
ADD A,#24H
MOV B,#0E3H ;第一區間的斜率
MOV R4,#80H ;第一區間的平方根基數
SJMP SQR3
SQR1: MOV B,#0B2H ;第二區間的斜率
MOV R4,#0A0H;第二區間的平方根基數
SJMP SQR3
SQR2: MOV B,#8DH ;第三區間的斜率
MOV R4,#0D0H;第三區間的平方根基數
SQR3: MUL AB ;與區間基點的偏移量乘區間斜率
MOV A,B
ADD A,R4 ;累加到平方根的基數上
MOV R4,A
MOV B,A
MUL AB ;求當前平方根的冪
XCH A,R3 ;求偏移量(存放在R2R3中)
CLR C
SUBB A,R3
MOV R3,A
MOV A,R2
SUBB A,B
MOV R2,A
SQR4: SETB C ;用減奇數法校正一個字節的平方根
MOV A,R4 ;當前平方根的兩倍加一存入R5R6中
RLC A
MOV R6,A
CLR A
RLC A
MOV R5,A
MOV A,R3 ;偏移量小于該奇數否？
SUBB A,R6
MOV B,A
MOV A,R2
SUBB A,R5
JC SQR5 ;小于,校正結束,已達到一個字節的精度
INC R4 ;不小于,平方根加一
MOV R2,A ;保存新的偏移量
MOV R3,B
SJMP SQR4 ;繼續校正
SQR5: MOV A,R4 ;將一個字節精度的根存入R2
XCH A,R2
RRC A
MOV F0,C ;保存最終偏移量的最高位
MOV A,R3
MOV R5,A ;將最終偏移量的低八位存入R5中
MOV R4,#8 ;通過(R5R6/R2)求根的低字節
SQR6: CLR C
MOV A,R3
RLC A
MOV R3,A
CLR C
MOV A,R5
SUBB A,R2
JB F0,SQR7
JC SQR8
SQR7: MOV R5,A
INC R3
SQR8: CLR C
MOV A,R5
RLC A
MOV R5,A
MOV F0,C
DJNZ R4,SQR6 ;根的第二字節計算完,在R3中
MOV A,R7 ;取原被開方數的左規次數
JZ SQRE ;未左規,開方結束
SQR9: CLR C ;按左規次數右移平方根,得到實際根
MOV A,R2
RRC A
MOV R2,A
MOV A,R3
RRC A
MOV R3,A
DJNZ R7,SQR9
SQRE: RET
(14) 標號: HASC功能:單字節十六進制數轉換成雙字節ASCII碼

入口條件:待轉換的單字節十六進制數在累加器A中。
出口信息:高四位的ASCII碼在A中,低四位的ASCII碼在B中。
影響資源:PSW、A、B 堆棧需求: 4字節

HASC: MOV B,A ;暫存待轉換的單字節十六進制數
LCALL HAS1 ;轉換低四位
XCH A,B ;存放低四位的ASCII碼
SWAP A ;準備轉換高四位
HAS1: ANL A,#0FH ;將累加器的低四位轉換成ASCII碼
ADD A,#90H
DA A
ADDC A,#40H
DA A
RET

(15) 標號: ASCH 功能:ASCII碼轉換成十六進制數

入口條件:待轉換的ASCII碼(30H~39H或41H~46H)在A中。
出口信息:轉換后的十六進制數(00H~0FH)仍在累加器A中。
影響資源:PSW、A 堆棧需求: 2字節

ASCH: CLR C
SUBB A,#30H
JNB ACC.4,ASH1
SUBB A,#7
ASH1: RET

(16) 標號:HBCD功能:單字節十六進制整數轉換成單字節BCD碼整數

入口條件:待轉換的單字節十六進制整數在累加器A中。
出口信息:轉換后的BCD碼整數(十位和個位)仍在累加器A中,百位在R3中。
影響資源:PSW、A、B、R3 堆棧需求: 2字節

HBCD: MOV B,#100 ;分離出百位,存放在R3中
DIV AB
MOV R3,A
MOV A,#10 ;余數繼續分離十位和個位
XCH A,B
DIV AB
SWAP A
ORL A,B ;將十位和個位拼裝成BCD碼
RET

(17) 標號: HB2功能:雙字節十六進制整數轉換成雙字節BCD碼整數

入口條件:待轉換的雙字節十六進制整數在R6、R7中。
出口信息:轉換后的三字節BCD碼整數在R3、R4、R5中。
影響資源:PSW、A、R2~R7 堆棧需求: 2字節

HB2: CLR A ;BCD碼初始化
MOV R3,A
MOV R4,A
MOV R5,A
MOV R2,#10H ;轉換雙字節十六進制整數
HB3: MOV A,R7 ;從高端移出待轉換數的一位到CY中
RLC A
MOV R7,A
MOV A,R6
RLC A
MOV R6,A
MOV A,R5 ;BCD碼帶進位自身相加,相當于乘2
ADDC A,R5
DA A ;十進制調整
MOV R5,A
MOV A,R4
ADDC A,R4
DA A
MOV R4,A
MOV A,R3
ADDC A,R3
MOV R3,A ;雙字節十六進制數的萬位數不超過6,不用調整
DJNZ R2,HB3 ;處理完16bit
RET

(18) 標號: HBD功能:單字節十六進制小數轉換成單字節BCD碼小數

入口條件:待轉換的單字節十六進制小數在累加器A中。
出口信息:CY=0時轉換后的BCD碼小數仍在A中。CY=1時原小數接近整數1。
影響資源:PSW、A、B 堆棧需求: 2字節

HBD: MOV B,#100 ;原小數擴大一百倍
MUL AB
RLC A ;余數部分四舍五入
CLR A
ADDC A,B
MOV B,#10 ;分離出十分位和百分位
DIV AB
SWAP A
ADD A,B ;拼裝成單字節BCD碼小數
DA A ;調整后若有進位,原小數接近整數1
RET

(19) 標號: HBD2功能:雙字節十六進制小數轉換成雙字節BCD碼小數

入口條件:待轉換的雙字節十六進制小數在R2、R3中。
出口信息:轉換后的雙字節BCD碼小數仍在R2、R3中。
影響資源:PSW、A、B、R2、R3、R4、R5 堆棧需求:6字節

HBD2: MOV R4,#4 ;四位十進制碼
HBD3: MOV A,R3 ;原小數擴大十倍
MOV B,#10
MUL AB
MOV R3,A
MOV R5,B
MOV A,R2
MOV B,#10
MUL AB
ADD A,R5
MOV R2,A
CLR A
ADDC A,B
PUSH ACC ;保存溢出的一位十進制碼
DJNZ R4,HBD3 ;計算完四位十進制碼
POP ACC ;取出萬分位
MOV R3,A
POP ACC ;取出千分位
SWAP A
ORL A,R3 ;拼裝成低字節BCD碼小數
MOV R3,A
POP ACC ;取出百分位
MOV R2,A
POP ACC ;取出十分位
SWAP A
ORL A,R2 ;拼裝成高字節BCD碼小數
MOV R2,A
RET
(20)標號:BCDH功能:單字節BCD碼整數轉換成單字節十六進制整數

入口條件:待轉換的單字節BCD碼整數在累加器A中。
出口信息:轉換后的單字節十六進制整數仍在累加器A中。
影響資源:PSW、A、B、R4 堆棧需求: 2字節

BCDH: MOV B,#10H ;分離十位和個位
DIV AB
MOV R4,B ;暫存個位
MOV B,#10 ;將十位轉換成十六進制
MUL AB
ADD A,R4 ;按十六進制加上個位
RET

(21)標號: BH2功能:雙字節BCD碼整數轉換成雙字節十六進制整數

入口條件:待轉換的雙字節BCD碼整數在R2、R3中。
出口信息:轉換后的雙字節十六進制整數仍在R2、R3中。
影響資源:PSW、A、B、R2、R3、R4 堆棧需求:4字節

BH2: MOV A,R3 ;將低字節轉換成十六進制
LCALL BCDH
MOV R3,A
MOV A,R2 ;將高字節轉換成十六進制
LCALL BCDH
MOV B,#100 ;擴大一百倍
MUL AB
ADD A,R3 ;和低字節按十六進制相加
MOV R3,A
CLR A
ADDC A,B
MOV R2,A
RET

(22)標號: BHD功能:單字節BCD碼小數轉換成單字節十六進制小數

入口條件:待轉換的單字節BCD碼數在累加器A中。
出口信息:轉換后的單字節十六進制小數仍在累加器A中。
影響資源:PSW、A、R2、R3 堆棧需求: 2字節

BHD: MOV R2,#8 ;準備計算一個字節小數
BHD0: ADD A,ACC ;按十進制倍增
DA A
XCH A,R3
RLC A ;將進位標志移入結果中
XCH A,R3
DJNZ R2,BHD0 ;共計算8bit小數
ADD A,#0B0H ;剩余部分達到0．50否？
JNC BHD1 ;四舍
INC R3 ;五入
BHD1: MOV A,R3 ;取結果
RET

(23)標號: BHD2功能:雙字節BCD碼小數轉換成雙字節十六進制小數

入口條件:待轉換的雙字節BCD碼小數在R4、R5中。
出口信息:轉換后的雙字節十六進制小數在R2、R3中。*
影響資源:PSW、A、R2~R6 堆棧需求: 2字節

BHD2: MOV R6,#10H ;準備計算兩個字節小數
BHD3: MOV A,R5 ;按十進制倍增
ADD A,R5
DA A
MOV R5,A
MOV A,R4
ADDC A,R4
DA A
MOV R4,A
MOV A,R3 ;將進位標志移入結果中
RLC A
MOV R3,A
MOV A,R2
RLC A
MOV R2,A
DJNZ R6,BHD3 ;共計算16bit小數
MOV A,R4
ADD A,#0B0H ;剩余部分達到0．50否？
JNC BHD4 ;四舍
INC R3 ;五入
MOV A,R3
JNZ BHD4
INC R2
BHD4: RET
(24) 標號: MM功能:求單字節十六進制無符號數據塊的極值

入口條件:數據塊的首址在DPTR中,數據個數在R7中。
出口信息:最大值在R6中,地址在R2R3中;最小值在R7中,地址在R4R5中。
影響資源:PSW、A、B、R1~R7 堆棧需求: 4字節

MM: MOV B,R7 ;保存數據個數
MOVX A,@DPTR ;讀取第一個數據
MOV R6,A ;作為最大值的初始值
MOV R7,A ;也作為最小值的初始值
MOV A,DPL ;取第一個數據的地址
MOV R3,A ;作為最大值存放地址的初始值
MOV R5,A ;也作為最小值存放地址的初始值
MOV A,DPH
MOV R2,A
MOV R4,A
MOV A,B ;取數據個數
DEC A ;減一,得到需要比較的次數
JZ MME ;只有一個數據,不需要比較
MOV R1,A ;保存比較次數
PUSH DPL ;保護數據塊的首址
PUSH DPH
MM1: INC DPTR ;指向一個新的數據
MOVX A,@DPTR ;讀取這個數據
MOV B,A ;保存
SETB C ;與最大值比較
SUBB A,R6
JC MM2 ;不超過當前最大值,保持當前最大值
MOV R6,B ;超過當前最大值,更新最大值存放地址
MOV R2,DPH ;同時更新最大值存放地址
MOV R3,DPL
SJMP MM3
MM2: MOV A,B ;與最小值比較
CLR C
SUBB A,R7
JNC MM3 ;大于或等于當前最小值,保持當前最小值
MOV R7,B ;更新最小值
MOV R4,DPH ;更新最小值存放地址
MOV R5,DPL
MM3: DJNZ R1,MM1 ;處理完全部數據
POP DPH ;恢復數據首址
POP DPL
MME: RET

(25) 標號: MMS功能:求單字節十六進制有符號數據塊的極值

入口條件:數據塊的首址在DPTR中,數據個數在R7中。
出口信息:最大值在R6中, 地址在R2R3中;最小值在R7中,地址在R4R5中。
影響資源:PSW、A、B、R1~R7 堆棧需求: 4字節

MMS: MOV B,R7 ;保存數據個數
MOVX A,@DPTR ;讀取第一個數據
MOV R6,A ;作為最大值的初始值
MOV R7,A ;也作為最小值的初始值
MOV A,DPL ;取第一個數據的地址
MOV R3,A ;作為最大值存放地址的初始值
MOV R5,A ;也作為最小值存放地址的初始值
MOV A,DPH
MOV R2,A
MOV R4,A
MOV A,B ;取數據個數
DEC A ;減一,得到需要比較的次數
JZ MMSE ;只有一個數據,不需要比較
MOV R1,A ;保存比較次數
PUSH DPL ;保護數據塊的首址
PUSH DPH
MMS1: INC DPTR ;調整數據指針
MOVX A,@DPTR ;讀取一個數據
MOV B,A ;保存
SETB C ;與最大值比較
SUBB A,R6
JZ MMS4 ;相同,不更新最大值
JNB OV,MMS2 ;差未溢出,符號位有效
CPL ACC.7 ;差溢出,符號位取反
MMS2: JB ACC.7,MMS4;差為負,不更新最大值
MOV R6,B ;更新最大值
MOV R2,DPH ;更新最大值存放地址
MOV R3,DPL
SJMP MMS7
MMS4: MOV A,B ;與最小值比較
CLR C
SUBB A,R7
JNB OV,MMS6 ;差未溢出,符號位有效
CPL ACC.7 ;差溢出,符號位取反
MMS6: JNB ACC.7,MMS7;差為正,不更新最小值
MOV R7,B ;更新最小值
MOV R4,DPH ;更新最小值存放地址
MOV R5,DPL
MMS7: DJNZ R1,MMS1 ;處理完全部數據
POP DPH ;恢復數據首址
POP DPL
MMSE: RET
(26) 標號: FDS1功能:順序查找(ROM)單字節表格

入口條件:待查找的內容在A中,表格首址在DPTR中,表格的字節數在R7中。
出口信息:OV=0時,順序號在累加器A中;OV=1時,未找到。
影響資源:PSW、A、B、R2、R6 堆棧需求: 2字節

FDS1: MOV B,A ;保存待查找的內容
MOV R2,#0 ;順序號初始化(指向表首)
MOV A,R7 ;保存表格的長度
MOV R6,A
FD11: MOV A,R2 ;按順序號讀取表格內容
MOVC A,@A+DPTR
CJNE A,B,FD12;與待查找的內容比較
CLR OV ;相同,查找成功
MOV A,R2 ;取對應的順序號
RET
FD12: INC R2 ;指向表格中的下一個內容
DJNZ R6,FD11 ;查完全部表格內容
SETB OV ;未查找到,失敗
RET

(27) 標號: FDS2功能:順序查找(ROM)雙字節表格

入口條件:查找內容在R4、R5中,表格首址在DPTR中,數據總個數在R7中。
出口信息:OV=0時順序號在累加器A中,地址在DPTR中;OV=1時未找到。
影響資源:PSW、A、R2、R6、DPTR 堆棧需求: 2字節

FDS2: MOV A,R7 ;保存表格中數據的個數
MOV R6,A
MOV R2,#0 ;順序號初始化(指向表首)
FD21: CLR A ;讀取表格內容的高字節
MOVC A,@A+DPTR
XRL A,R4 ;與待查找內容的高字節比較
JNZ FD22
MOV A,#1 ;讀取表格內容的低字節
MOVC A,@A+DPTR
XRL A,R5 ;與待查找內容的低字節比較
JNZ FD22
CLR OV ;相同,查找成功
MOV A,R2 ;取對應的順序號
RET
FD22: INC DPTR ;指向下一個數據
INC DPTR
INC R2 ;順序號加一
DJNZ R6,FD21 ;查完全部數據
SETB OV ;未查找到,失敗
RET

(28) 標號:FDD1功能:對分查找(ROM)單字節無符號增序數據表格

入口條件:待查找的內容在累加器A中,表格首址在DPTR中,字節數在R7中。
出口信息:OV=0 時,順序號在累加器A中;OV=1 時,未找到。
影響資源:PSW、A、B、R2、R3、R4 堆棧需求:2字節

FDD1: MOV B,A ;保存待查找的內容
MOV R2,#0 ;區間低端指針初始化(指向第一個數據)
MOV A,R7
DEC A
MOV R3,A ;區間高端指針初始化(指向最后一個數據)
FD61: CLR C ;判斷區間大小
MOV A,R3
SUBB A,R2
JC FD69 ;區間消失,查找失敗
RRC A ;取區間大小的一半
ADD A,R2 ;加上區間的低端
MOV R4,A ;得到區間的中心
MOVC A,@A+DPTR;讀取該點的內容
CJNE A,B,FD65;與待查找的內容比較
CLR OV ;相同,查找成功
MOV A,R4 ;取順序號
RET
FD65: JC FD68 ;該點的內容比待查找的內容大否？
MOV A,R4 ;偏大,取該點位置
DEC A ;減一
MOV R3,A ;作為新的區間高端
SJMP FD61 ;繼續查找
FD68: MOV A,R4 ;偏小,取該點位置
INC A ;加一
MOV R2,A ;作為新的區間低端
SJMP FD61 ;繼續查找
FD69: SETB OV ;查找失敗
RET
(29) 標號:FDD2功能:對分查找(ROM)雙字節無符號增序數據表格

入口條件:查找內容在R4、R5中,表格首址在DPTR中,數據個數在R7中。
出口信息:OV=0 時順序號在累加器A中,址在DPTR中;OV=1 時未找到。
影響資源:PSW、A、B、R1~R7、DPTR 堆棧需求:2字節

FDD2: MOV R2,#0 ;區間低端指針初始化(指向第一個數據)
MOV A,R7
DEC A
MOV R3,A ;區間高端指針初始化,指向最后一個數據
MOV R6,DPH ;保存表格首址
MOV R7,DPL
FD81: CLR C ;判斷區間大小
MOV A,R3
SUBB A,R2
JC FD89 ;區間消失,查找失敗
RRC A ;取區間大小的一半
ADD A,R2 ;加上區間的低端
MOV R1,A ;得到區間的中心
MOV DPH,R6
CLR C ;計算區間中心的地址
RLC A
JNC FD82
INC DPH
FD82: ADD A,R7
MOV DPL,A
JNC FD83
INC DPH
FD83: CLR A ;讀取該點的內容的高字節
MOVC A,@A+DPTR
MOV B,R4 ;與待查找內容的高字節比較
CJNE A,B,FD84;不相同
MOV A,#1 ;讀取該點的內容的低字節
MOVC A,@A+DPTR
MOV B,R5
CJNE A,B,FD84;與待查找內容的低字節比較
MOV A,R1 ;取順序號
CLR OV ;查找成功
RET
FD84: JC FD86 ;該點的內容比待查找的內容大否？
MOV A,R1 ;偏大,取該點位置
DEC A ;減一
MOV R3,A ;作為新的區間高端
SJMP FD81 ;繼續查找
FD86: MOV A,R1 ;偏小,取該點位置
INC A ;加一
MOV R2,A ;作為新的區間低端
SJMP FD81 ;繼續查找
FD89: MOV DPH,R6 ;相同,恢復首址
MOV DPL,R7
SETB OV ;查找失敗
RET


(30) 標號: DDM1功能:求單字節十六進制無符號數據塊的平均值

入口條件:數據塊的首址在DPTR中,數據個數在R7中。
出口信息:平均值在累加器A中。
影響資源:PSW、A、R2~R6 堆棧需求: 4字節

DDM1: MOV A,R7 ;保存數據個數
MOV R2,A
PUSH DPH
PUSH DPL
CLR A ;初始化累加和
MOV R4,A
MOV R5,A
DM11: MOVX A,@DPTR ;讀取一個數據
ADD A,R5 ;累加到累加和中
MOV R5,A
JNC DM12
INC R4
DM12: INC DPTR ;調整指針
DJNZ R2,DM11 ;累加完全部數據
LCALL D457 ;求平均值(R4R5/R7-→R3)
MOV A,R3 ;取平均值
POP DPL
POP DPH
RET

(31) 標號: DDM2功能:求雙字節十六進制無符號數據塊的平均值

入口條件:數據塊的首址在DPTR中,雙字節數據總個數在R7中。
出口信息:平均值在R4、R5中。
影響資源:PSW、A、R2~R6 堆棧需求: 4字節

DDM2: MOV A,R7 ;保存數據個數
MOV R2,A ;初始化數據指針
PUSH DPL ;保持首址
PUSH DPH
CLR A ;初始化累加和
MOV R3,A
MOV R4,A
MOV R5,A
DM20: MOVX A,@DPTR ;讀取一個數據的高字節
MOV B,A
INC DPTR
MOVX A,@DPTR ;讀取一個數據的低字節
INC DPTR
ADD A,R5 ;累加到累加和中
MOV R5,A
MOV A,B
ADDC A,R4
MOV R4,A
JNC DM21
INC R3
DM21: DJNZ R2,DM20 ;累加完全部數據
POP DPH ;恢復首址
POP DPL
LJMP DV31 ;求R3R4R5/R7-→R4R5,得到平均值

(32) 標號: XR1功能:求單字節數據塊的(異或)校驗和

入口條件:數據塊的首址在DPTR中,數據的個數在R6、R7中。
出口信息:校驗和在累加器A中。
影響資源:PSW、A、B、R4~R7 堆棧需求: 2字節

XR1: MOV R4,DPH ;保存數據塊的首址
MOV R5,DPL
MOV A,R7 ;雙字節計數器調整
JZ XR10
INC R6
XR10: MOV B,#0 ;校驗和初始化
XR11: MOVX A,@DPTR ;讀取一個數據
XRL B,A ;異或運算
INC DPTR ;指向下一個數據
DJNZ R7,XR11 ;雙字節計數器減一
DJNZ R6,XR11
MOV DPH,R4 ;恢復數據首址
MOV DPL,R5
MOV A,B ;取校驗和
RET

(33) 標號: XR2功能:求雙字節數據塊的(異或)校驗和

入口條件:數據塊的首址在DPTR中,雙字節數據總個數在R6、R7中。
出口信息:校驗和在R2、R3中。
影響資源:PSW、A、R2~R7 堆棧需求: 2字節

XR2: MOV R4,DPH ;保存數據塊的首址
MOV R5,DPL
MOV A,R7 ;雙字節計數器調整
JZ XR20
INC R6
XR20: CLR A ;校驗和初始化
MOV R2,A
MOV R3,A
XR21: MOVX A,@DPTR ;讀取一個數據的高字節
XRL A,R2 ;異或運算
MOV R2,A
INC DPTR
MOVX A,@DPTR ;讀取一個數據的低字節
XRL A,R3 ;異或運算
MOV R3,A
INC DPTR ;指向下一個數據
DJNZ R7,XR21 ;雙字節計數器減一
DJNZ R6,XR21
MOV DPH,R4 ;恢復數據首址
MOV DPL,R5
RET

(34) 標號: SORT功能:單字節無符號數據塊排序(增序)

入口條件:數據塊的首址在R0中,字節數在R7中。
出口信息:完成排序(增序)
影響資源:PSW、A、R2~R6 堆棧需求: 2字節

SORT: MOV A,R7
MOV R5,A ;比較次數初始化
SRT1: CLR F0 ;交換標志初始化
MOV A,R5 ;取上遍比較次數
DEC A ;本遍比上遍減少一次
MOV R5,A ;保存本遍次數
MOV R2,A ;復制到計數器中
JZ SRT5 ;若為零,排序結束
MOV A,R0 ;保存數據指針
MOV R6,A
SRT2: MOV A,@R0 ;讀取一個數據
MOV R3,A
INC R0 ;指向下一個數據
MOV A,@R0 ;再讀取一個數據
MOV R4,A
CLR C
SUBB A,R3 ;比較兩個數據的大小
JNC SRT4 ;順序正確(增序或相同),不必交換
SETB F0 ;設立交換標志
MOV A,R3 ;將兩個數據交換位置
MOV @R0,A
DEC R0
MOV A,R4
MOV @R0,A
INC R0 ;指向下一個數據
SRT4: DJNZ R2,SRT2 ;完成本遍的比較次數
MOV A,R6 ;恢復數據首址
MOV R0,A
JB F0,SRT1 ;本遍若進行過交換,則需繼續排序
SRT5: RET ;排序結束
END