;*********************************************************************
; 公司名稱:
; 模塊名稱:DS1302.a51
; 功 能:實時時鐘模塊 時鐘芯片型號:DS1302
; 說 明:(修改版)
; 程序設計:zhaojunjie
; 設計時間:2002.05.04
; 版 本 號:20020504
;*********************************************************************
;**********************************************************
;子程序名:Set1302
;功 能:設置DS1302 初始時間,并啟動計時。
;說 明:
;調 用:RTInputByte
;入口參數:初始時間在:Second,Minute,Hour,Day,Month,Week.YearL(地址連續)
;出口參數:無
;影響資源:A B R0 R1 R4 R7
;設 計:zhaojunjie 日 期:2002-03-19
;修 改: 日 期:
;**********************************************************
Set1302:
CLR T_RST
CLR T_CLK
SETB T_RST
MOV B,#8EH ;控制寄存器
LCALL RTInputByte
MOV B,#00H ;寫操作前WP=0
LCALL RTInputByte
SETB T_CLK
CLR T_RST
MOV R0,#Second;
MOV R7,#7 ;秒 分 時 日 月 星期 年
MOV R1,#80H ;秒寫地址
S13021: CLR T_RST
CLR T_CLK
SETB T_RST
MOV B, R1 ;寫秒 分 時 日 月 星期 年 地址
LCALL RTInputByte
MOV A,@R0 ;寫秒數據
MOV B,A
LCALL RTInputByte
INC R0
INC R1
INC R1
SETB T_CLK
CLR T_RST
DJNZ R7, S13021
CLR T_RST
CLR T_CLK
SETB T_RST
MOV B,#8EH ;控制寄存器
LCALL RTInputByte
MOV B,#80H ;控制,WP=1,寫保護
LCALL RTInputByte
SETB T_CLK
CLR T_RST
RET
;**********************************************************
;子程序名:Get1302
;功 能:從DS1302 讀時間
;說 明:
;調 用:RTInputByte,RTOutputByte
;入口參數:時間保存在:Second,Minute,Hour,Day,Month,Week.YearL
;出口參數:無
;影響資源:A B R0 R1 R4 R7
;設 計:zhaojunjie 日 期:2002-03-19
;修 改: 日 期:
;**********************************************************
Get1302:
MOV R0,#Second;
MOV R7,#7
MOV R1,#81H ;秒地址
G13021: CLR T_RST
CLR T_CLK
SETB T_RST
MOV B,R1 ;秒 分 時 日 月 星期 年 地址
LCALL RTInputByte
LCALL RTOutputByte
MOV @R0,A ;秒
INC R0
INC R1
INC R1
SETB T_CLK
CLR T_RST
DJNZ R7,G13021
RET
;**********************************************************
;功 能:寫1302一字節 (內部子程序)
;**********************************************************
RTInputByte:
MOV R4,#8
Inbit1: MOV A,B
RRC A
MOV B,A
MOV T_IO,C
SETB T_CLK
CLR T_CLK
DJNZ R4,Inbit1
RET
;**********************************************************
;功 能:讀1302一字節 (內部子程序)
;**********************************************************
RTOutputByte:
MOV R4,#8
Outbit1: MOV C,T_IO
RRC A
SETB T_CLK
CLR T_CLK
DJNZ R4,Outbit1
RET
;/////////////////////////////////////////////////////////////////////////////
