我這幾天在玩24C02讀寫程序，總是失敗。后來無意中才發現，原來原理圖和實際電路板不符：原理圖上24C02的SDA和SCL分別接P3.4和P3.5，而實際電路板正好相反。改正程序后便成功了。故在此提醒大家，免得像我一樣走了彎路。
在此提供大家24C02的讀寫子程序，供大家參考學習。
SDA24 EQU P3.5
SCLK24 EQU P3.4

;讀24C02子程序。地址放在A中，讀出數據也在A中。
RD24: PUSH ACC
SETB SDA24
CLR SCLK24
ACALL START24
MOV A,#0A0H
ACALL SHIFT8
ACALL ACK
POP ACC
ACALL SHIFT8
ACALL ACK
ACALL START24
MOV A,#0A1H
ACALL SHIFT8
ACALL ACK
SETB SDA24
MOV R7,#8
CLR A
SETB SDA24
RD000:
SETB SCLK24
MOV C,SDA24
RLC A
CLR SCLK24
DJNZ R7,RD000
RET
;-------------------------------
;寫入24C02程序。地址放在A中，要寫入的數據放在B中。
WT24: PUSH ACC
SETB SDA24
CLR SCLK24
ACALL START24
MOV A,#0A0H
ACALL SHIFT8
ACALL ACK
POP ACC
ACALL SHIFT8
ACALL ACK
MOV A,B
ACALL SHIFT8
ACALL ACK
ACALL STOP
ACALL DELAY2
RET
;*-*-*-*-*-*-*-*-*-*-*-*-*-*-*-*-*-*-*-*-*-*-*-*-*-*-*-*-*-*-*-
;以下為底層子程序，不面向用戶。
;開始條件
START24:CLR SDA24
SETB SDA24
SETB SCLK24
CLR SDA24
CLR SCLK24
RET
;停止條件
STOP: CLR SDA24
SETB SCLK24
SETB SDA24
RET
;應答信號
ACK: SETB SCLK24
CLR SCLK24
RET
;寫數據
SHIFT8:MOV R7,#8
SH01: RLC A
MOV SDA24,C
SETB SCLK24
CLR SCLK24
DJNZ R7,SH01
RET
DELAY2:
NOP
NOP
NOP
NOP
RET

---

2008-8-27 9:02:45 [51dz]〖218.17.42.69〗：非常謝謝你的無私奉獻以及指正！祝你學習進步！